blob: 7f0398c15908b282515b29bc6f183cd80e459585 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: txtsd <aur.archlinux@ihavea.quest>
pkgname=llama.cpp-sycl-f32
_pkgname=${pkgname%%-sycl-f32}
pkgver=b5827
pkgrel=1
pkgdesc="Port of Facebook's LLaMA model in C/C++ (with Intel SYCL GPU optimizations and F32)"
arch=(x86_64 armv7h aarch64)
url='https://github.com/ggerganov/llama.cpp'
license=('MIT')
depends=(
curl
gcc-libs
glibc
intel-oneapi-basekit
python
python-numpy
python-sentencepiece
)
makedepends=(
cmake
git
procps-ng
)
optdepends=(python-pytorch)
provides=(${_pkgname})
conflicts=(${_pkgname} libggml)
options=(lto !debug !buildflags)
source=(
"git+${url}#tag=${pkgver}"
llama.cpp.conf
llama.cpp.service
)
sha256sums=('0e8737ea89c77dc16348aac4b9bd2e589290e3eb5cf8e03f6b067d329eb532f9'
'53fa70cfe40cb8a3ca432590e4f76561df0f129a31b121c9b4b34af0da7c4d87'
'0377d08a07bda056785981d3352ccd2dbc0387c4836f91fb73e6b790d836620d')
build() {
source /opt/intel/oneapi/setvars.sh
local _cmake_options=(
-B build
-S "${_pkgname}"
-DCMAKE_BUILD_TYPE=Release
-DCMAKE_INSTALL_PREFIX='/usr'
-DBUILD_SHARED_LIBS=ON
-DLLAMA_CURL=ON
-DLLAMA_BUILD_TESTS=OFF
-DLLAMA_USE_SYSTEM_GGML=OFF
-DGGML_ALL_WARNINGS=OFF
-DGGML_ALL_WARNINGS_3RD_PARTY=OFF
-DGGML_BUILD_EXAMPLES=OFF
-DGGML_BUILD_TESTS=OFF
-DGGML_LTO=ON
-DGGML_RPC=ON
-DCMAKE_C_COMPILER=icx
-DCMAKE_CXX_COMPILER=icpx
-DGGML_SYCL=ON
-Wno-dev
)
cmake "${_cmake_options[@]}"
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install build
install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "llama.cpp.conf" "${pkgdir}/etc/conf.d/llama.cpp"
install -Dm644 "llama.cpp.service" "${pkgdir}/usr/lib/systemd/system/llama.cpp.service"
}
|