blob: 658ac8a808f305bac6bf4a8a81a371bb9080228c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
pkgname=lldpd-git
pkgver=0.7.8.12
pkgrel=1
pkgdesc="LLDP daemon for GNU/Linux implementing both reception and sending"
arch=('i686' 'x86_64')
url="http://vincentbernat.github.io/lldpd/"
license=('custom:"ISC"')
depends=('libxml2' 'net-snmp' 'libevent' 'libbsd' 'jansson')
makedepends=('git')
provides=('lldpd')
conflicts=('lldpd')
options=('!libtool')
install=lldpd.install
backup=('etc/lldpd.conf')
source=("$pkgname::git+https://github.com/vincentbernat/lldpd.git"
'lldpd.service'
'lldpd.install'
'LICENSE')
md5sums=('SKIP'
'73eaa8101f84e787138aee3927455c36'
'76d6b0e0d5d0de3718dbca898d0db270'
'8ae98663bac55afe5d989919d296f28a')
pkgver() {
cd $pkgname
git describe --tags --always | sed 's|-|.|g;s|[.]g[a-f0-9]*$||'
}
build() {
cd $pkgname
./autogen.sh
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--with-snmp \
--with-xml \
--with-json \
--with-privsep-user=lldpd \
--with-privsep-group=lldpd \
--with-privsep-chroot=/run/lldpd \
--with-lldpd-ctl-socket=/run/lldpd.socket \
--with-lldpd-pid-file=/run/lldpd.pid
make
echo "" >>lldpd.conf
echo "# Place configuration files in this directory: see lldpcli(8)" >README.conf
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
install -Dm644 lldpd.conf "$pkgdir/etc/lldpd.conf"
install -Dm644 README.conf "$pkgdir/etc/lldpd.d/README"
install -Dm644 ../lldpd.service "$pkgdir/usr/lib/systemd/system/lldpd.service"
install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|