blob: f1f5833a034e44d3244b94d078897d7f946c3a11 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Porous3247 <pqtb3v7t at jasonyip1 dot anonaddy dot me>
# Contributor: Asuka Minato <asukaminato at nyan dot eu dot org>
_pkgname="llm"
pkgname="${_pkgname}-git"
pkgver=r572.8a8076f
pkgrel=1
pkgdesc="Run inference for Large Language Models on CPU, with Rust 🦀🚀🦙"
arch=(any)
url="https://github.com/rustformers/${_pkgname}"
license=('MIT' 'APACHE')
depends=(glibc gcc-libs)
makedepends=(git cargo)
provides=(llm)
conflicts=(llm)
replaces=(llama-cli)
source=("git+${url}"
"git+https://github.com/ggerganov/ggml"
)
sha256sums=('SKIP' 'SKIP')
prepare() {
cd "${srcdir}/${_pkgname}"
git submodule init
git config submodule.crates/ggml/sys/ggml.url "${srcdir}/ggml"
git -c protocol.file.allow=always submodule update
}
pkgver() {
cd "${srcdir}/${_pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${_pkgname}"
cargo build --release
cat LICENSE-* > LICENSE
}
package() {
cd "${srcdir}/${_pkgname}"
install -Dm755 target/release/llm -t "${pkgdir}/usr/bin/"
install -Dm644 README.md -t "${pkgdir}/usr/share/doc/${_pkgname}/"
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|