blob: f6e6794692674bf18368946db75b156c54949e2f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Sagnik Mandal <criticic>
# Contributor: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Eli Schwartz <eschwartz@archlinux.org>
# Contributor: earnestly
pkgname=llpp
pkgver=36
pkgrel=1
pkgdesc='opengl accelerated pdf viewer based on mupdf'
arch=('x86_64')
url=https://github.com/criticic/llpp
cloneurl=https://github.com/criticic/llpp
license=('GPL3')
depends=('freetype2' 'gumbo-parser' 'jbig2dec' 'libgl' 'libjpeg' 'openjpeg2')
makedepends=('asciidoc' 'git' 'libmupdf' 'ocaml' 'ocaml-lablgl')
optdepends=('djvulibre: for llppac djvu conversion'
'ghostscript: for llppac ps, dvi, and djvu conversion'
'imagemagick: for llppac image conversion'
'inotify-tools: for the llpp.inotify autoreload wrapper'
'librsvg: for llppac svg conversion'
'unoconv: for llppac office conversion')
options=('!strip')
source=("git+$cloneurl#tag=v$pkgver"
'system-makedeps.patch')
b2sums=('SKIP'
'ea03064061fd97ce7a4ef218709c9897f1df57dc4a3e71c2df1ef19fb187dfa04922fff5e3cc4d29caa08fbc9ae7073317bdf4f66a687695a20a840c37b44787')
prepare() {
cd $pkgname
patch --forward --strip=1 --input=../system-makedeps.patch
# Restore desktop file
git revert --no-commit aad4b1e65e581ff7a096a3c3901b222a9c127a1c
}
build() {
cd $pkgname
bash ./build.bash build
bash ./build.bash build doc
}
package() {
cd $pkgname
install -Dt "$pkgdir"/usr/bin build/llpp misc/llpp{.inotify,ac}
install -Dm644 -t "$pkgdir"/usr/share/applications misc/llpp.desktop
install -Dm644 -t "$pkgdir"/usr/share/man/man1 build/doc/*.1
}
|