blob: c9fe55cc705d7d14e4b8ffa5375311a165d36acc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=lmdb-git
pkgver=0.9.30.r22965.g6b77544ab
pkgrel=2
pkgdesc="Extraordinarily fast, memory-efficient database"
arch=('i686' 'x86_64')
url="https://symas.com/lmdb/"
license=('custom')
depends=('glibc')
makedepends=('git')
provides=("lmdb=$pkgver")
conflicts=('lmdb')
options=('staticlibs')
source=("git+https://git.openldap.org/openldap/openldap.git"
"lmdb.pc::https://gitlab.archlinux.org/archlinux/packaging/packages/lmdb/-/raw/main/lmdb.pc")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "openldap/libraries/liblmdb"
git describe --long --tags | sed 's/^LMDB_//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "openldap/libraries/liblmdb"
make
}
check() {
cd "openldap/libraries/liblmdb"
make test
}
package() {
cd "openldap/libraries/liblmdb"
make \
DESTDIR="$pkgdir" \
prefix="/usr" \
install
sed -e "s|@PKGVER@|$pkgver|" -i "$srcdir/lmdb.pc"
install -Dm644 "$srcdir/lmdb.pc" -t "$pkgdir/usr/lib/pkgconfig"
install -Dm644 {COPYRIGHT,LICENSE} -t "$pkgdir/usr/share/licenses/lmdb"
}
|