blob: 32158e3fe6d10eaae15bb5b1430fefe7356a40ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
|
# Maintainer:
# Contributor: Patrick Northon <northon_patrick3@yahoo.ca>
: ${CARGO_HOME:=$SRCDEST/cargo-home}
: ${CARGO_TARGET_DIR:=target}
: ${RUSTUP_TOOLCHAIN:=stable}
export CARGO_HOME CARGO_TARGET_DIR RUSTUP_TOOLCHAIN
: ${FVM_CACHE_PATH:=$SRCDEST/fvm-cache}
export FVM_CACHE_PATH
: ${_use_sodeps:=false}
: ${_install_path:=usr/lib}
_pkgname="localsend"
pkgname="$_pkgname"
pkgver=1.18.2
pkgrel=2
pkgdesc="An open source cross-platform alternative to AirDrop"
url="https://github.com/localsend/localsend"
license=('Apache-2.0')
arch=('x86_64' 'aarch64')
depends=(
'at-spi2-core'
'cairo'
'fontconfig'
'gdk-pixbuf2'
'glib2'
'gtk3'
'hicolor-icon-theme'
'libayatana-appindicator'
'libepoxy'
'pango'
)
makedepends=(
'cargo'
'clang'
'cmake'
'fvm'
'git'
'lld'
'llvm'
'ninja'
'patchelf'
)
options=('!lto')
_pkgsrc="$_pkgname-$pkgver"
_pkgext="tar.gz"
source=("$_pkgsrc.$_pkgext"::"$url/archive/refs/tags/v$pkgver.$_pkgext")
sha256sums=('4425dfcf2e016d6540ea44941deb4ba6568201cc47d7f08753606e6e4b2769cd')
_rust_setup() {
if [ -n "$_arch" ]; then
return
fi
# bypass Cargokit rustup requirement to use system toolchain
if ! pacman -Qs rustup &> /dev/null; then
install -Dm755 /dev/stdin fakebin/rustup << END
#!/usr/bin/env true
END
fi
if [ -e "$srcdir/fakebin" ]; then
export PATH="$srcdir/fakebin:$PATH"
fi
_arch="x64"
if [[ "${CARCH::1}" == "a" ]]; then
_arch="arm64"
fi
local _units=$(($(nproc) > 16 ? $(nproc) : 16))
export CARGO_PROFILE_RELEASE_LTO=false
export CARGO_PROFILE_RELEASE_CODEGEN_UNITS=$_units
}
prepare() {
_rust_setup
cd "$_pkgsrc"
cargo fetch --locked --target host-tuple
}
build() {
_rust_setup
export CXXFLAGS+=' -Wno-error=deprecated-declarations'
cd "$_pkgsrc"
cargo build --frozen --release --all-features
# copy isolate for flutter to find
local _isolates="app/build/linux/$_arch/release/plugins/rust_lib_localsend_app"
mkdir -p "$_isolates"
cp "$srcdir/$_pkgsrc/$CARGO_TARGET_DIR/release/librust_lib_localsend_app.so" "$_isolates/"
cd "app"
fvm install
fvm flutter --disable-analytics
#fvm flutter pub upgrade --major-versions
fvm flutter --no-version-check pub get
fvm flutter build linux --no-pub --release
}
package() {
_rust_setup
if [[ "${_use_sodeps::1}" == "t" ]]; then
eval "depends+=(
libatk-1.0.so
libcairo.so
libepoxy.so
libfontconfig.so
libgdk-3.so
libgdk_pixbuf-2.0.so
libgio-2.0.so
libglib-2.0.so
libgobject-2.0.so
libgtk-3.so
libpango-1.0.so
libpangocairo-1.0.so
)"
fi
# cli, server
install -Dm755 "$_pkgsrc/$CARGO_TARGET_DIR/release"/{localsend-cli,server} -t "$pkgdir/$_install_path/$_pkgname/"
# app, lib, data
cd "$_pkgsrc/app/build/linux/$_arch/release/bundle"
install -Dm755 "localsend_app" -t "$pkgdir/$_install_path/$_pkgname"
cp -r lib/ "$pkgdir/$_install_path/$_pkgname/"
cp -r data/ "$pkgdir/$_install_path/$_pkgname/"
# runpath
for i in "$pkgdir/$_install_path/$_pkgname"{,/lib}/*; do
if [ -f "$i" ] && readelf -h "$i" &> /dev/null; then
if [[ "$i" =~ /lib/[^/]+$ ]]; then
printf 'Setting rpath to $ORIGIN for %s ...\n' "${i##*/}"
patchelf --set-rpath '$ORIGIN' "$i"
else
printf 'Setting rpath to $ORIGIN/lib for %s ...\n' "${i##*/}"
patchelf --set-rpath '$ORIGIN/lib' "$i"
fi
fi
done
# symlink
mkdir -pm755 "${pkgdir}/usr/bin"
ln -sfr "$pkgdir/$_install_path/$_pkgname/${_pkgname}_app" "$pkgdir/usr/bin/${_pkgname}"
ln -sfr "$pkgdir/$_install_path/$_pkgname/${_pkgname}-cli" "$pkgdir/usr/bin/${_pkgname}-cli"
# icon
install -Dm644 "$srcdir/$_pkgsrc/app/build/flutter_assets/assets/img/logo-512.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/$_pkgname.png"
# launcher
install -Dm644 /dev/stdin "$pkgdir/usr/share/applications/$_pkgname.desktop" << END
[Desktop Entry]
Type=Application
Name=LocalSend
Comment=$pkgdesc
Exec=$_pkgname
Icon=$_pkgname
Terminal=false
Categories=Utility;Network;
StartupWMClass=Org.localsend.localsend_app
END
# license
install -Dm644 "$srcdir/$_pkgsrc/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
# permissions
chmod -R u+rwX,go+rX,go-w "$pkgdir/"
}
|