PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

pkgname=('log4cplus-git')
srcname='log4cplus'
pkgver='r1'
pkgrel='1'
pkgdesc='Simple to use C++ logging API providing thread-safe, flexible, and arbitrarily granular control over log management and configuration'
arch=('i686' 'x86_64')
url='https://github.com/log4cplus/log4cplus'
license=('custom:BSD' 'Apache')

depends=('gcc-libs')
makedepends=('git' 'gcc-libs')
provides=('log4cplus')
conflicts=('log4cplus')

source=("${srcname}::git+https://github.com/log4cplus/log4cplus.git")
sha512sums=('SKIP')

pkgver() {
    cd "${srcdir}/${srcname}"

    printf 'r%s.%s\n' \
        "$( git rev-list HEAD | wc --lines )" \
        "$( git describe --always | sed 's/-/./g' )"
}

prepare() {
    cd "${srcdir}/${srcname}"

    autoreconf --install

    ./configure \
        --prefix='/usr' \
        --with-working-locale
}

build() {
    cd "${srcdir}/${srcname}"

    make
}

package() {
    cd "${srcdir}/${srcname}"

    make DESTDIR="${pkgdir}" install
}