blob: 9da6504c5b0ae58381b7496e997288cb336711b6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id$
# Maintainer: Pierre Schmitz <pierre@archlinux.de>
# SELinux Maintainer: Nicolas Iooss (nicolas <dot> iooss <at> m4x <dot> org)
pkgname=logrotate-selinux
pkgver=3.14.0
pkgrel=1
pkgdesc="Rotates system logs automatically with SELinux support"
arch=('x86_64')
url="https://github.com/logrotate/logrotate"
license=('GPL')
groups=('selinux')
depends=('popt' 'gzip' 'acl' 'libselinux')
conflicts=("${pkgname/-selinux}" "selinux-${pkgname/-selinux}")
provides=("${pkgname/-selinux}=${pkgver}-${pkgrel}"
"selinux-${pkgname/-selinux}=${pkgver}-${pkgrel}")
backup=('etc/logrotate.conf')
source=("https://github.com/logrotate/logrotate/releases/download/${pkgver}/${pkgname/-selinux}-${pkgver}.tar.xz"{,.asc}
'logrotate.conf')
md5sums=('1c0f6e6e490c4bcac0a1e77ad1310683'
'SKIP'
'94dae4d3eded2fab9ae879533d3680db')
validpgpkeys=('992A96E075056E79CD8214F9873DB37572A37B36')
build() {
cd "$srcdir/${pkgname/-selinux}-${pkgver}"
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--mandir=/usr/share/man \
--with-compress-command=/usr/bin/gzip \
--with-uncompress-command=/usr/bin/gunzip \
--with-default-mail-command=/usr/bin/mail \
--with-acl \
--with-selinux
make
}
check() {
cd "$srcdir/${pkgname/-selinux}-${pkgver}"
make test
}
package() {
cd "$srcdir/${pkgname/-selinux}-${pkgver}"
make DESTDIR="$pkgdir" install
install -dm755 "$pkgdir/etc/logrotate.d"
install -Dm644 "$srcdir/logrotate.conf" "$pkgdir/etc/logrotate.conf"
install -D -m644 examples/logrotate.timer ${pkgdir}/usr/lib/systemd/system/logrotate.timer
install -D -m644 examples/logrotate.service ${pkgdir}/usr/lib/systemd/system/logrotate.service
install -d -m755 $pkgdir/usr/lib/systemd/system/timers.target.wants
ln -s ../logrotate.timer $pkgdir/usr/lib/systemd/system/timers.target.wants/logrotate.timer
}
|