PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: voidlesity <me@voidlesity.dev>

pkgname=logseq-desktop-nightly-bin
pkgver=20261010
_appver=2.0.2-alpha
pkgrel=1
pkgdesc="Nightly build of Logseq, a privacy-first, open-source knowledge management platform"
arch=('x86_64' 'aarch64')
url="https://github.com/logseq/logseq"
license=('AGPL-3.0-or-later')
depends=('gtk3' 'nss' 'nspr' 'alsa-lib' 'mesa' 'libxkbcommon' 'libxcomposite' 'libxdamage' 'libxrandr' 'at-spi2-core' 'libcups' 'libsecret' 'desktop-file-utils')
provides=('logseq-desktop')
conflicts=('logseq-desktop')
options=('!strip')
install="$pkgname.install"

source=('logseq.desktop'
        "logseq.png::$url/raw/nightly/resources/icons/logseq.png")
source_x86_64=("$pkgname-$pkgver.zip::$url/releases/download/nightly/Logseq-linux-x86_64-$_appver+nightly.$pkgver.zip")
source_aarch64=("$pkgname-$pkgver.zip::$url/releases/download/nightly/Logseq-linux-arm64-$_appver+nightly.$pkgver.zip")
noextract=("$pkgname-$pkgver.zip")

sha256sums=('1d2ca6e23e6cdff83e58fbe9e1ef27da2091556f3cbab8aed86dd1aa158d6f05'
            'e3801c054138a9cc5eb555c0cea985620716ddf621421369213da82b9fff557a')
sha256sums_x86_64=('c7e8dd7b0c493846a1f04ee653c8e3659b915d8286e8ed990a1c5d57b13f5857')
sha256sums_aarch64=('c7e8dd7b0c493846a1f04ee653c8e3659b915d8286e8ed990a1c5d57b13f5857')

package() {
  # App files (the zip has no top-level folder, so extract it straight in).
  install -dm755 "$pkgdir/opt/$pkgname"
  bsdtar -xf "$pkgname-$pkgver.zip" -C "$pkgdir/opt/$pkgname"

  install -dm755 "$pkgdir/usr/bin"
  ln -s "/opt/$pkgname/logseq" "$pkgdir/usr/bin/logseq"

  install -Dm644 logseq.desktop "$pkgdir/usr/share/applications/logseq.desktop"
  install -Dm644 logseq.png "$pkgdir/usr/share/pixmaps/logseq.png"
}