summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ed78691a7f75f5bde2159ca5eac87615fc6386a8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: Charlie Ringström <c.ringstrom@gmail.com>
pkgname='longcat'
pkgver=r113.f0ff33e
pkgrel=2
pkgdesc="Creates a loooonng cat in the terminal"
arch=('i686' 'pentium4' 'x86_64' 'arm' 'armv7h' 'armv6h' 'aarch64')
url="https://github.com/mattn/longcat"
license=('MIT')
depends=('glibc')
makedepends=('go')
#changelog="Initial release"
source=("longcat::git://github.com/mattn/longcat.git")
md5sums=('SKIP')

pkgver() {
  cd "$pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$pkgname"
	export CGO_CPPFLAGS="${CPPFLAGS}"
	export CGO_CFLAGS="${CFLAGS}"
 	export CGO_CXXFLAGS="${CXXFLAGS}"
 	export CGO_LDFLAGS="${LDFLAGS}"
 	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
	go build -o longcat
}

package() {
	cd "$pkgname"
	install -Dm755 ./longcat "$pkgdir"/usr/bin/$pkgname
	install -Dm644 ./LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}