blob: 9238c880c9037f160a2e8caf2e743ac8669497f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Omar Pakker <archlinux@opakker.nl>
pkgbase=looking-glass
pkgname=("${pkgbase}"
"${pkgbase}-module-dkms"
"${pkgbase}-host"
"obs-plugin-${pkgbase}")
epoch=2
pkgver=B4
pkgrel=2
pkgdesc="An extremely low latency KVMFR (KVM FrameRelay) implementation for guests with VGA PCI Passthrough"
url="https://looking-glass.io/"
arch=('x86_64')
license=('GPL2')
makedepends=('cmake' 'fontconfig' 'spice-protocol' 'wayland-protocols'
'libxss' 'libxi' 'obs-studio')
source=("looking-glass-${pkgver}.tar.gz::https://looking-glass.io/artifact/${pkgver}/source")
sha512sums=('800b89438719dba1794db9e0b97fa1271ad0410cb92c62e8b680f73db948325c98afebd7cd26c05dd8c3a8c0c8565b5625409ce26797a1c635aaf4be01e509c8')
_lgdir="${pkgbase}-${pkgver}"
build() {
cd "${srcdir}/${_lgdir}"
for b in {client,host,obs}/build; do
mkdir "${b}"
pushd "${b}"
cmake -DCMAKE_INSTALL_PREFIX=/usr ..
make
popd
done
}
package_looking-glass() {
pkgdesc="A client application for accessing the LookingGlass IVSHMEM device of a VM"
depends=('libgl' 'libegl' 'nettle' 'fontconfig' 'libxss' 'libxi' 'libxinerama')
cd "${srcdir}/${_lgdir}/client/build"
make DESTDIR="${pkgdir}" install
}
package_looking-glass-module-dkms() {
pkgdesc="A kernel module that implements a basic interface to the IVSHMEM device for when using LookingGlass in VM->VM mode"
depends=('dkms')
cd "${srcdir}/${_lgdir}/module"
install -Dm644 -t "${pkgdir}/usr/src/${pkgbase}-${pkgver}" \
Makefile \
dkms.conf \
kvmfr.{h,c}
}
package_looking-glass-host() {
pkgdesc="Linux host application for pushing frame data to the LookingGlass IVSHMEM device"
depends=('libxcb' 'zlib')
cd "${srcdir}/${_lgdir}/host/build"
make DESTDIR="${pkgdir}" install
}
package_obs-plugin-looking-glass() {
pkgdesc="Plugin for OBS Studio to stream directly from Looking Glass without having to record the Looking Glass client"
depends=('obs-studio')
install -Dm644 -t "${pkgdir}/usr/lib/obs-plugins" \
"${srcdir}/${_lgdir}/obs/build/liblooking-glass-obs.so"
}
|