blob: 2e405fc4c75fb247919d12628cf7cc4ac193bff1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Omar Pakker <archlinux@opakker.nl>
pkgbase=looking-glass
pkgname=("${pkgbase}" "${pkgbase}-module-dkms" "${pkgbase}-host")
epoch=2
pkgver=B1
_pkgver=${pkgver//_/-}
pkgrel=3
pkgdesc="An extremely low latency KVMFR (KVM FrameRelay) implementation for guests with VGA PCI Passthrough"
url="https://looking-glass.hostfission.com"
arch=('x86_64')
license=('GPL2')
makedepends=('cmake' 'sdl2_ttf' 'glu' 'fontconfig' 'spice-protocol')
source=("https://github.com/gnif/LookingGlass/archive/${_pkgver}.tar.gz"
"https://github.com/gnif/LookingGlass/pull/241.diff")
sha512sums=('add82702d7e7f601a07db5b9e0de7a7472d3051a71c4cb484e0c10333f25e0ca54d19513002b93803ae1677fb8ea05368253cd929853dfcda16207a53ed2f19f'
'ecf3a2d45a5393410ddc93444c01174745cddc9c07b52347c7e3635b4e1ce3d87cf6c332f8767034f1a219603f929ab2f821c7157f564b630de4d0eba11045f0')
prepare() {
cd "${srcdir}/LookingGlass-${_pkgver}"
patch -i "${srcdir}/241.diff" -u common/src/crash.linux.c
}
build() {
cd "${srcdir}/LookingGlass-${_pkgver}"
for b in {client,c-host}; do
pushd "${b}"
cmake -DCMAKE_INSTALL_PREFIX=/usr .
make
popd
done
}
package_looking-glass() {
pkgdesc="A client application for accessing the LookingGlass IVSHMEM device of a VM"
depends=('sdl2_ttf' 'glu' 'nettle' 'fontconfig')
cd "${srcdir}/LookingGlass-${_pkgver}/client"
make DESTDIR="${pkgdir}" install
}
package_looking-glass-module-dkms() {
pkgdesc="A kernel module that implements a basic interface to the IVSHMEM device for when using LookingGlass in VM->VM mode"
depends=('dkms')
cd "${srcdir}/LookingGlass-${_pkgver}/module"
for f in {Makefile,dkms.conf,kvmfr.c}; do
install -Dm644 "${f}" "${pkgdir}/usr/src/${pkgbase}-${pkgver}/${f}"
done
}
package_looking-glass-host() {
pkgdesc="Linux host application for pushing frame data to the LookingGlass IVSHMEM device"
depends=('libxcb' 'zlib')
cd "${srcdir}/LookingGlass-${_pkgver}/c-host"
make DESTDIR="${pkgdir}" install
}
|