blob: adec8aab6767552bd635ad84d1bb3d90ab1bb216 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: John Troxler <firstname dot lastname at gmail dot com>
# Co-Maintainer: Martin Rys <https://rys.pw/contact>
pkgname=loot
pkgver=0.21.0
_pkglibver=0.21.0
pkgrel=1
pkgdesc="A load order optimisation tool for the Elder Scrolls (Morrowind and later) and Fallout (3 and later) games."
arch=('x86_64')
url="https://loot.github.io"
license=('GPL3')
depends=('boost-libs' 'libssh2' 'alsa-lib' 'nss' 'pango' 'atk' 'libxdamage' 'libxcomposite' 'libxcursor' 'libxrandr' 'libxss' 'libxtst' 'qt6-base')
makedepends=('git' 'cmake' 'rust' 'cbindgen' 'boost' 'onetbb')
source=("$pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$pkgname/archive/$pkgver.tar.gz"
"lib$pkgname-$_pkglibver.tar.gz::https://github.com/$pkgname/lib$pkgname/archive/$_pkglibver.tar.gz"
'LOOT.desktop'
)
sha256sums=('e729a1da8ae6eb28a444370c7dbe3f0eb6c502fe99cce96487935a70df4e713d'
'9cdf082670b71d1f3c89e3916e9dbc3a41a12cc74f55613a897a93f1c9f4a267'
'3dd063fdbe33dc82a4298bd5bcd3b4e7490adab4128389c153d12c6b074b27fb'
)
# https://github.com/loot/loot/issues/1920
prepare() {
sed -i 's/ICU 71.1 EXACT/ICU 71.1/' "${srcdir}/${pkgname}-${pkgver}/CMakeLists.txt"
sed -i 's/ICU 71.1 EXACT/ICU 71.1/' "${srcdir}/lib${pkgname}-${pkgver}/CMakeLists.txt"
}
build() {
# libloot
cd "$srcdir/lib$pkgname-$_pkglibver"
mkdir -p build
cd build
cmake .. -DCMAKE_SKIP_RPATH=TRUE
make loot
mkdir -p pkg
cp lib$pkgname.so ./pkg/
cp -r ../include/ ./pkg/
tar -zcf lib$pkgname-$_pkglibver.tar.gz ./pkg/
# loot
cd "$srcdir/$pkgname-$pkgver"
mkdir -p build
cd build
cmake .. -DLIBLOOT_URL="$srcdir/lib$pkgname-$_pkglibver/build/lib$pkgname-$_pkglibver.tar.gz" \
-DCMAKE_BUILD_WITH_INSTALL_RPATH=TRUE -DCMAKE_INSTALL_RPATH="/opt/$pkgname"
make LOOT
}
package() {
_builddir="$srcdir/$pkgname-$pkgver/build"
install -Dm755 -t "$pkgdir/opt/$pkgname" \
"$_builddir/LOOT" \
"$_builddir/lib$pkgname.so"
mkdir -p "$pkgdir/usr/bin"
ln -s "/opt/$pkgname/LOOT" "$pkgdir/usr/bin"
# Install the icon
install -Dm644 "${_builddir}/../resources/icons/loot.svg" "${pkgdir}/usr/share/icons/hicolor/scalable/apps/loot.svg"
# Install desktop entry
install -Dm644 "${srcdir}/LOOT.desktop" "${pkgdir}/usr/share/applications/LOOT.desktop"
}
|