PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Contributor: Philip Goto <philip.goto@gmail.com>
# Contributor: Fabian Bornschein <fabiscafe@archlinux.org>

_pkgname=loupe
pkgname=loupe-git
pkgver=48.0.r3.g89ae7b6
pkgrel=1
pkgdesc="simple image viewer for GNOME"
arch=(x86_64 aarch64)
url="https://gitlab.gnome.org/GNOME/loupe"
license=('GPL-3.0-or-later')
depends=(
  cairo
  dconf
  gcc-libs
  desktop-file-utils
  glib2
  glibc
  glycin
  graphene
  gtk4-git
  hicolor-icon-theme
  lcms2
  libadwaita-git
  libgweather-4
  libseccomp
)
makedepends=(
  git
  itstool
  meson
  rust
)
provides=(loupe)
conflicts=(loupe)
source=("git+$url.git")
b2sums=('SKIP')

# Use LTO
export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1

# Use debug
export CARGO_PROFILE_RELEASE_DEBUG=2

pkgver() {
  cd $_pkgname
  git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd $_pkgname
}

build() {
  arch-meson $_pkgname build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir" --no-rebuild
}