blob: 70681a9a791e0e05c30a23b4c796b5d904a5a8dc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Carl Klemm <carl@uvos.xyz>
pkgname=lovr
pkgver=0.19.0
pkgrel=1
pkgdesc='Lua Virtual Reality Framework, a VR game engine'
arch=('x86_64')
url='https://lovr.org/'
license=('MIT')
depends=('glibc' 'libgcc' 'libx11' 'libstdc++' 'glfw' 'luajit' 'openxr')
makedepends=('git' 'cmake' 'glslang')
source=("git+https://github.com/bjornbytes/lovr.git#tag=v0.19.0"
"Vulkan-Headers::git+https://github.com/KhronosGroup/Vulkan-Headers"
"joltc::git+https://github.com/amerkoleci/joltc"
"lovr-http::git+https://github.com/bjornbytes/lovr-http"
"lua-enet::git+https://github.com/bjornbytes/lua-enet"
"msdfgen::git+https://github.com/bjornbytes/msdfgen"
"openxr-sdk::git+https://github.com/khronosgroup/openxr-sdk"
"enet::git+https://github.com/lsalzman/enet")
sha256sums=(
"SKIP"
"SKIP"
"SKIP"
"SKIP"
"SKIP"
"SKIP"
"SKIP"
"SKIP"
)
prepare() {
repo="${pkgname}"
git -C $repo submodule init
git -C $repo config submodule.deps/joltc.url "file://$srcdir/joltc"
git -C $repo config submodule.deps/msdfgen.url "file://$srcdir/msdfgen"
git -C $repo config submodule.deps/vulkan-headers.url "file://$srcdir/Vulkan-Headers"
git -C $repo config submodule.plugins/lovr-http.url "file://$srcdir/lovr-http"
git -C $repo config submodule.plugins/lua-enet.url "file://$srcdir/lua-enet"
git -C $repo -c protocol.file.allow=always submodule update
repo="${pkgname}/plugins/lua-enet"
git -C $repo submodule init
git -C $repo config submodule.enet.url "file://$srcdir/enet"
git -C $repo -c protocol.file.allow=always submodule update
}
build() {
cmake -B build -S "${pkgname}" \
-G 'Unix Makefiles' \
-Wno-dev \
-DCMAKE_C_FLAGS=-lm \
-DLOVR_SYSTEM_LUA=On \
-DLOVR_SYSTEM_GLFW=On \
-DLOVR_SYSTEM_OPENXR=On \
-DLOVR_USE_GLSLANG=Off \
-DCMAKE_INSTALL_PREFIX=/usr
cmake --build build
}
package() {
install -D -m755 "$srcdir/build/bin/lovr" -t "${pkgdir}/usr/bin"
install -D -m755 "$srcdir/build/bin/libjoltc.so" -t "${pkgdir}/usr/lib"
install -D -m755 "$srcdir/build/bin/libmsdfgen.so" -t "${pkgdir}/usr/lib"
install -D -m644 "$srcdir/lovr/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|