summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7e7966616c80c2a5509d41160dd768d3530ec713 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Frederik “Freso” S. Olesen <archlinux@freso.dk>
_pkgname=low-memory-monitor
pkgname=${_pkgname}-git
pkgver=r79.5e06b3b
pkgrel=1
pkgdesc='Early boot daemon monitoring memory pressure information and invokes OOM if needed'
arch=('x86_64')
url="https://gitlab.freedesktop.org/hadess/${_pkgname}"
license=('GPL3')
depends=('systemd')
makedepends=('meson' 'git' 'gtk-doc')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("git+$url.git")
sha512sums=('SKIP')

pkgver() {
	cd "$srcdir/${_pkgname}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/${_pkgname}"
	meson --prefix /usr --buildtype=plain ./ build
	ninja -C build
}

check() {
	cd "$srcdir/${_pkgname}"
	ninja -C build test
}

package() {
	cd "$srcdir/${_pkgname}"
	DESTDIR="$pkgdir" ninja -C build install
}