PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

pkgname=lpcscrypt
pkgver=2.0.0.831
pkgrel=0
pkgdesc="Programming tool for LPC1800 and LPC4000 series microcontrollers"
arch=('x86_64')
url="https://www.nxp.com/support/developer-resources/software-development-tools/lpc-developer-resources-/lpc-microcontroller-utilities/lpcscrypt-v2.0.0:LPCSCRYPT"
license=('proprietary')
makedepends=(libarchive unmakeself)
depends=(dfu-util libutil-linux)
optdepends=(bash)

_pkgver_main=${pkgver%.*}
_pkgver_rel=${pkgver##*.}
_pkgver_u=${_pkgver_main}_${_pkgver_rel}
_src="$pkgname-$_pkgver_u.x86_64.deb.bin"
source=("https://www.nxp.com/downloads/en/software/$_src")
sha384sums=('4b3a61b502b4232a1d0605f1c600a7125e57a36378efe879d97873ebc72de243e694200cb6c4e3e0a7f6520920f17855')

prepare() {
    mkdir -p $pkgname-$_pkgver_u
    cd $pkgname-$_pkgver_u
    unmakeself ../$_src
    bsdtar xf "$pkgname-$_pkgver_u.x86_64.deb"
    tar xf data.tar.gz
}

package() {
    cd "$srcdir/$pkgname-$_pkgver_u"

    install -D -v -m644 ProductLicense.txt "$pkgdir/usr/share/licenses/$pkgname/license.txt"
    
    _s="usr/local/$pkgname-$_pkgver_u"

    _o="$pkgdir/opt/$pkgname"
    mkdir -p "$_o"
    cp -r "$_s/"* "$_o"

    install -D -v -m644 "$_s/scripts/99-lpcscrypt.rules" -t "$pkgdir/usr/lib/udev/rules.d"
    rm -f "$_o/scripts/99-lpcscrypt.rules"
    rm -f "$_o/scripts/install_udev_rules"
}