PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Tony Lambiris <tony@libpcap.net>

pkgname=lte-cell-scanner-git
pkgver=r26.e7f71cb
pkgrel=3
pkgdesc="An OpenCL accelerated TDD/FDD LTE Scanner"
arch=('i686' 'x86_64')
url="https://github.com/JiaoXianjun/LTE-Cell-Scanner"
license=('GPL')
depends=('boost-libs' 'itpp')
makedepends=('git' 'cmake' 'hackrf' 'fftw' 'boost' 'bladerf' 'rtl-sdr' 'blas')
source=("${pkgname}::git+https://github.com/JiaoXianjun/LTE-Cell-Scanner")
sha256sums=('SKIP')

pkgver() {
	cd "$pkgname"

	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd "$pkgname"
	#'system' needs to be removed from this line or it won't compile
	sed -i 's/FIND_PACKAGE( Boost COMPONENTS thread system REQUIRED )/FIND_PACKAGE( Boost COMPONENTS thread REQUIRED )/' CMakeLists.txt
}

build() {
	cd "$pkgname"
	local cmake_options=(
		-B build
		-DCMAKE_BUILD_TYPE=Release
		-DCMAKE_INSTALL_PREFIX=/usr
		-DCMAKE_VERBOSE_MAKEFILE=ON
		-DUSE_HACKRF=1
		-DUSE_BLADERF=1
		-DUSE_RTLSDR=1
		-DCMAKE_POLICY_VERSION_MINIMUM=3.5
		-DUSE_OPENCL=0 # opencl segfaults in some cases
	)
	cmake "${cmake_options[@]}"
	cmake --build build
}

package() {
	cd "$pkgname"
	DESTDIR="$pkgdir" cmake --install build
}