blob: 35d6d4d7c47fcd7fc8b63ed48189d2116fb852e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Alex Sarum <rum.274.4 at gmail dot com>
pkgname='ltrace-git'
pkgver=0.7.91.r1410.gea8928d
pkgrel=1
pkgdesc="Debugging program to track runtime library calls in dynamically linked programs"
arch=('x86_64')
url="http://www.ltrace.org/"
license=('GPL2')
depends=('libelf' 'libunwind')
makedepends=('git' 'autoconf')
provides=('ltrace')
conflicts=('ltrace')
source=("$pkgname::git+https://gitlab.com/cespedes/ltrace")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$pkgname"
release=$(grep -oe "AC_INIT(\[ltrace\],\[[0-9.]*\]" configure.ac | grep -oe "[0-9.]*")
count_commits=$(git rev-list --count HEAD)
commit=$(git rev-parse --short HEAD)
echo "${release}.r${count_commits}.g$commit"
}
build() {
cd "$srcdir/$pkgname"
autoreconf -i
./configure --prefix=/usr \
--sysconfdir=/etc \
--without-elfutils \
--with-libunwind \
--disable-werror
make
}
check() {
cd "$srcdir/$pkgname"
make -k check || true
}
package() {
cd "$srcdir/$pkgname"
make DESTDIR="$pkgdir/" install
}
# vim:set ts=2 sw=2 et:
|