PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Caleb Maclennan <caleb@alerque.com>

_rockname=lsqlite3
pkgname=("lua-$_rockname" "lua52-$_rockname" "lua51-$_rockname")
pkgver=0.9.5
_fossilver=fsl09y
_rockrel=1
pkgrel=1
pkgdesc="A binding for Lua to the SQLite3 database library"
arch=('i686' 'x86_64')
url='http://lua.sqlite.org'
license=('MIT')
_lua_deps=('sqlite')
makedepends=('luarocks')
source=("$_rockname-$pkgver.zip::http://lua.sqlite.org/index.cgi/zip/lsqlite3_$_fossilver.zip?uuid=${_fossilver/0/_}")
sha256sums=('72498d89056ada0d03a2053224dc887bf7535eb75d006232be14ef7824848818')

_package_helper() {
  cd "${_rockname}_$_fossilver"
  luarocks --lua-version=$1 --tree="$pkgdir/usr/" make --deps-mode=none --no-manifest "$_rockname-$pkgver-$_rockrel.rockspec"
}

package_lua-lsqlite3() {
  depends+=('lua' "${_lua_deps[@]/#/lua-}")
  _package_helper 5.3
}

package_lua52-lsqlite3() {
  depends+=('lua52' "${_lua_deps[@]/#/lua52-}")
  _package_helper 5.2
}

package_lua51-lsqlite3() {
  depends+=('lua51' "${_lua_deps[@]/#/lua51-}")
  _package_helper 5.1
}