summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5c3140aaa94ea740d18c81abd7c8fcf4fef6836c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Caleb Maclennan <caleb@alerque.com>

_rockname=mediator
_pkgname=mediator_lua
pkgname=("lua-$_rockname" "lua53-$_rockname" "lua52-$_rockname" "lua51-$_rockname")
pkgname=lua-mediator
pkgver=1.1.2
_rockrel=0
pkgrel=4
pkgdesc='Event handling through channels'
arch=('any')
url="https://olivinelabs.com/$_pkgname/"
license=('MIT')
makedepends=('lua' 'lua53' 'lua52' 'lua51' 'luarocks')
source=("${_rockname}-${pkgver}.tar.gz::https://github.com/Olivine-Labs/$_pkgname/archive/v$pkgver-$_rockrel.tar.gz")
sha256sums=('faf5859fd2081be4e9e4fb8873a2dc65f7eff3fd93d6dd14da65f8e123fcff9b')

_package_helper() {
  cd "$_pkgname-$pkgver-$_rockrel"
  luarocks --lua-version=$1 --tree="$pkgdir/usr/" \
    make --deps-mode=none --no-manifest "$_pkgname-$pkgver-$_rockrel.rockspec"
}

package_lua-mediator() {
  depends+=('lua')
  _package_helper 5.4
}

package_lua53-mediator() {
  depends+=('lua53')
  _package_helper 5.3
}

package_lua52-mediator() {
  depends+=('lua52')
  _package_helper 5.2
}

package_lua51-mediator() {
  depends+=('lua51')
  _package_helper 5.1
}