blob: a64202909482a69113c75a571a5749974a7dcc19 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>
_pkgname=penlight
pkgname=("lua-$_pkgname-git" "lua53-$_pkgname-git" "lua52-$_pkgname-git" "lua51-$_pkgname-git")
pkgver=1.8.0.r0.g76079c1
pkgrel=1
pkgdesc='Lua libraries for on input data handling, functional programming, and OS interface'
url='https://tieske.github.io/Penlight'
arch=('any')
license=('MIT')
_lua_deps=('filesystem')
makedepends=('lua' 'lua53' 'lua52' 'lua51')
checkdepends=('lua' "${_lua_deps[@]/#/lua-}")
source=("$_pkgname::git+https://github.com/Tieske/Penlight.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags --abbrev=7 HEAD |
sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
check() {
cd "$_pkgname"
export LUA_PATH="$PWD/lua/?/init.lua;$PWD/lua/?.lua;$(lua -e 'print(package.path)')"
lua run.lua
}
_package_helper() {
cd "$_pkgname"
install -Dm 644 -t "$pkgdir/usr/share/lua/$1/pl" lua/pl/*
install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname/" CONTRIBUTING.md CHANGELOG.md README.md
install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname/manual/" docs/manual/*
install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname/examples/" examples/*
install -Dm 644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE.md
}
package_lua-penlight-git() {
depends+=('lua' "${_lua_deps[@]/#/lua-}")
provides=("${pkgname/%-git}")
conflicts=("${pkgname/%-git}")
_package_helper 5.4
}
package_lua53-penlight-git() {
depends+=('lua53' "${_lua_deps[@]/#/lua53-}")
provides=("${pkgname/%-git}")
conflicts=("${pkgname/%-git}")
_package_helper 5.3
}
package_lua52-penlight-git() {
depends+=('lua52' "${_lua_deps[@]/#/lua52-}")
provides=("${pkgname/%-git}")
conflicts=("${pkgname/%-git}")
_package_helper 5.2
}
package_lua51-penlight-git() {
depends+=('lua51' "${_lua_deps[@]/#/lua51-}")
provides=("${pkgname/%-git}")
conflicts=("${pkgname/%-git}")
_package_helper 5.1
}
|