blob: c19e2b474855bce611e6cc618cb5e8628123cd80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
pkgname=lua54
_pkgver=5.4.0
_pkgaver=$_pkgver-alpha
_pkgrver=$_pkgaver-rc2
pkgver=${_pkgrver//\-/_}
pkgrel=1
pkgdesc='Powerful lightweight programming language designed for extending applications'
arch=('x86_64')
url='https://www.lua.org/'
depends=('readline')
license=('MIT')
options=('!emptydirs')
source=(https://www.lua.org/work/lua-$_pkgrver.tar.gz
liblua.so.patch
lua.pc
LICENSE)
sha512sums=('410df708b89a53f73d4165014ed9353275404e0ae40704d7bd883724cfbeb9800022442de4e842998b4db18d6ee6bbd3ae7d35391a7d23fb1ea1edd9b94a01b2'
'09f5e567ea18e6bcd7d99384e136ffb091f8bfd6fac08a9ed97c549f9ba210214e1da363e07e9836e3610fb2a343ef572f159defbb12b3477412e2d92c6225dc'
'a3ae5f5c63a27956a2c69464cf966512be7404aef72d49b0b3b17e35999ceed04ec7be12ef19269f4cac908141b98dd5d16df9c238823fe0c1e068212914657a'
'bef221ae96e72d11785ec608ce96fa688ce4e12fecaaadc8c3e38d7d153922f4fdd2cf06a47e9f8840a165d42d9aa31f44c322f5c6c8402e8e31475de4e5893b')
prepare() {
cd lua-$_pkgaver
patch -p1 -i ../liblua.so.patch
sed "s/%VER%/${_pkgver%.*}/g;s/%REL%/$_pkgver/g" ../lua.pc > lua.pc
sed -e 's:llua:llua5.4:' -e 's:/include:/include/lua5.4:' -i lua.pc
sed -r -e '/^LUA_(SO|A|T)=/ s/lua/lua5.4/' -e '/^LUAC_T=/ s/luac/luac5.4/' -i src/Makefile
}
build() {
cd lua-$_pkgaver
make MYCFLAGS="$CFLAGS -fPIC -DLUA_COMPAT_5_1 -DLUA_COMPAT_5_2" MYLDFLAGS="$LDFLAGS" linux
}
package() {
cd lua-$_pkgaver
make \
TO_BIN='lua5.4 luac5.4' \
TO_LIB="liblua5.4.a liblua5.4.so liblua5.4.so.5.4 liblua5.4.so.$_pkgver" \
INSTALL_DATA='cp -d' \
INSTALL_TOP="$pkgdir"/usr \
INSTALL_INC="$pkgdir"/usr/include/lua5.4 \
INSTALL_MAN="$pkgdir"/usr/share/man/man1 \
install
install -Dm644 lua.pc "$pkgdir"/usr/lib/pkgconfig/$pkgname.pc
install -d "$pkgdir"/usr/share/doc/$pkgname
install -m644 doc/*.{gif,png,css,html} "$pkgdir"/usr/share/doc/$pkgname
install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
ln -s liblua5.4.so "$pkgdir"/usr/lib/liblua.so.5.4
ln -s liblua5.4.so "$pkgdir"/usr/lib/liblua.so.$_pkgver
cd "$pkgdir"/usr/share/man/man1
mv lua.1 lua5.4.1
mv luac.1 luac5.4.1
}
|