PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Sébastien Luttringer <seblu@archlinux.org>
# Contributor: Anders Bergh <anders1@gmail.com>

pkgbase=luasql
pkgname=(lua-sql-mysql lua-sql-postgres lua-sql-sqlite)
pkgver=2.8.1
pkgrel=1
arch=(x86_64)
url='https://keplerproject.github.io/luasql'
license=(MIT)
makedepends=(libmariadbclient
             lua
             postgresql-libs
             sqlite)
_archive="$pkgbase-$pkgver"
source=("https://github.com/keplerproject/luasql/archive/$pkgver/$_archive.tar.gz")
sha256sums=('4c5c890b53c5c085329e6d152f1f711c4bbc79234f85ed4371646802c91093a4')

build() {
	cd "$_archive"
	make sqlite3 PREFIX=/usr DRIVER_LIBS='-lsqlite3' DRIVER_INCS='-std=c99'
	make postgres PREFIX=/usr DRIVER_LIBS='-lpq' DRIVER_INCS='-std=c99'
	make mysql PREFIX=/usr DRIVER_LIBS="$(mysql_config --libs)" \
		DRIVER_INCS="$(mysql_config --include) -std=c99"
}

package_lua-sql-mysql() {
	pkgdesc='MySQL module for Lua'
	depends=(lua libmariadbclient)
	conflicts=(luasql-mysql)
	replaces=(luasql-mysql)
	cd "$_archive"
	install -Dm644 -t "$pkgdir/usr/lib/lua/5.3/luasql/" src/mysql.so
	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" doc/us/license.html
}

package_lua-sql-postgres() {
	pkgdesc='PostgreSQL module for Lua'
	depends=(lua postgresql-libs)
	cd "$_archive"
	install -Dm644 -t "$pkgdir/usr/lib/lua/5.3/luasql/" src/postgres.so
	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" doc/us/license.html
}

package_lua-sql-sqlite() {
	pkgdesc='SQLite module for Lua'
	depends=(lua sqlite)
	cd "$_archive"
	install -Dm644 -t "$pkgdir/usr/lib/lua/5.3/luasql/" src/sqlite3.so
	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" doc/us/license.html
}