blob: 0d408720ca0b9679b2542ae6fbd09bb73c1e6c01 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Saber0324 <saber 0324 at proton dot me>
# Contributor: Hog185 <hogman12333 at gmail dot com>
pkgname=lufus
pkgver=1.0.1
pkgrel=1
pkgdesc="Physical drive imaging and formatting utility for Linux written in Python"
arch=('any')
url="https://github.com/Hogjects/Lufus"
license=('MIT')
depends=(
'python'
'python-psutil'
'python-pyqt6'
'python-pyudev'
'python-requests'
'python-packaging'
'python-platformdirs'
'qt6-base'
'dosfstools'
'ntfs-3g'
'exfatprogs'
'e2fsprogs'
'udftools'
)
makedepends=(
'uv'
'python-installer'
)
source=(
"$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz"
"lufus.desktop"
)
sha256sums=('2c3f3317929f01080b63839ccf4b3c6794458caee66359ccaa86017964011ebd'
'b883901dc9f8b4baf354976c3782a8c3c14e0fe77b6d744479fa3a6a797d876c')
build() {
cd "Lufus-$pkgver"
UV_NO_SYNC=1 uv build --wheel --no-sources
}
package() {
cd "Lufus-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README"
install -Dm644 ../lufus.desktop "$pkgdir/usr/share/applications/lufus.desktop"
install -Dm644 src/lufus/gui/assets/lufus.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/lufus.png"
install -Dm755 /dev/stdin "$pkgdir/usr/bin/lufus" <<'LAUNCHER'
#!/usr/bin/env python
from lufus.__main__ import main
main()
LAUNCHER
}
|