blob: 38efc210a3fe831b0e9ac40af51843336d377908 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: spider-mario <spidermario@free.fr>
# Contributor: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: Dmitry N. Shilov <stormblast@land.ru>
pkgname=luminancehdr-git
pkgver=2.6.0.r298.gf5042b48
pkgrel=1
pkgdesc='Open source graphical user interface application that aims to provide a workflow for HDR imaging'
arch=('x86_64')
url='http://qtpfsgui.sourceforge.net/'
license=('GPL')
depends=('exiv2' 'fftw' 'gsl' 'lcms2' 'libraw' 'openexr' 'qt5-webengine' 'qt5-svg'
'ccfits' 'desktop-file-utils' 'hicolor-icon-theme' 'boost-libs')
makedepends=('git' 'cmake' 'boost' 'eigen' 'gtest' 'qt5-tools' 'patch')
optdepends=('hugin: align image stack functionality')
provides=('luminancehdr')
conflicts=('luminancehdr')
options=('!emptydirs')
source=('git+https://github.com/LuminanceHDR/LuminanceHDR.git'
'cmake-build-type.patch')
b2sums=('SKIP'
'759f5b096f4b72cb9a11e24d5e31983ba26d0b84d67e85d25551f482b88e0366ac0996020b6ae5f2a3340c8be9e6f2ed5fb5b52d59754ff3d7e9829796910c82')
pkgver() {
cd "${srcdir}"/LuminanceHDR
git describe --long | sed 's/^v\.//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}"/LuminanceHDR
git apply -3 ../cmake-build-type.patch
}
build() {
mkdir -p build
cd build
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=None \
"${srcdir}"/LuminanceHDR
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
}
|