blob: 604ef59f4d742bcdba20e67d99f156dfed7b95aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Victor Fuentes <hyruleterminatriforce@gmail.com>
# Contributor: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Michael DeGuzis <mdeguzis@gmail.com>
# Contributor: Frederik “Freso” S. Olesen <freso.dk@gmail.com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
pkgname=lutris-git
pkgver=0.5.8.2.r12.g1b321f40
pkgrel=1
pkgdesc='Open Gaming Platform'
arch=('any')
url='https://lutris.net/'
license=('GPL3')
depends=('python-gobject' 'python-yaml' 'python-evdev' 'python-dbus' 'gtk3'
'glib2' 'psmisc' 'cabextract' 'unzip' 'p7zip' 'curl'
'python-pillow' 'python-requests' 'webkit2gtk'
'mesa-demos' 'python-dbus' 'python-distro' 'python-magic-ahupp'
'python-lxml')
makedepends=('git' 'meson')
#checkdepends=('xorg-server-xvfb' 'python-nose-cover3' 'wine' 'xterm')
optdepends=(
'wine: easiest way to get all the libraries missing from the Lutris runtime'
'vulkan-icd-loader: Vulkan support'
'lib32-vulkan-icd-loader: Vulkan support'
'vkd3d: Vulkan 3D support'
'lib32-vkd3d: Vulkan 3D support'
'gvfs: GVFS backend'
'xorg-xrandr: fetch screen resolutions on Xorg'
'gnome-desktop: fetch screen resolutions on Wayland'
'lib32-glibc: for 32bit games support'
'python-evdev: for controller detection'
'python-pypresence: Discord RPC and Rich Presence'
'gamemode: Allows games to request a temporary set of optimisations'
"mangohud: Display the games' FPS + other information")
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/lutris/lutris.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
arch-meson "${pkgname%-git}" build
meson compile -C build
}
check() {
meson test -C build
# Tests fail in chroot
# cd "$srcdir/${pkgname%-git}"
# xvfb-run nosetests --cover-erase --with-xunit --xunit-file=nosetests.xml \
# --with-coverage --cover-package=lutris --cover-xml-file=coverage.xml
}
package() {
DESTDIR="$pkgdir" meson install -C build
}
|