PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Gordian Edenhofer <gordian.edenhofer@gmail.com>
# Submitter: Steffen L. Norgren (incongruous) <steffen[at]norgren[dot]ca>

pkgname=luv-icon-theme-git
pkgver=0.4.r95.g85c9234
pkgrel=1
pkgdesc="The spiritual successor to Flattr, a flat but complex icon theme for freedesktop environments."
arch=('any')
url="https://github.com/NitruxSA/luv-icon-theme"
license=('custom:CC BY-SA 4.0')
depends=('librsvg')
makedepends=('git')
provides=("flattr-icon-theme=${pkgver}" "luv-icon-theme=${pkgver}")
conflicts=('flattr-icon-theme' 'luv-icon-theme')
source=("${pkgname}"::'git+https://github.com/NitruxSA/luv-icon-theme.git')
sha512sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}"
	( set -o pipefail
	git describe --long --tags 2>/dev/null | sed 's/^luv.v//;s/\([^-]*-g\)/r\1/;s/-/./g' \
	|| printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

package() {
	cd "${srcdir}/${pkgname}"

	install -dm755 "${pkgdir}/usr/share/icons"
	cp -dpr --no-preserve=ownership ./Luv "${pkgdir}/usr/share/icons/"

	install -Dm644 "./Luv/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -Dm644 "./CREDITS" "${pkgdir}/usr/share/licenses/${pkgname}/CREDITS"
	rm "${pkgdir}/usr/share/icons/Luv/LICENSE"
}