blob: 00938363a40265f724818f04cfdea34d778b9c39 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer : bartus <arch-user-repoᘓbartus.33mail.com>
pkgname=luxcorerender
pkgver=2.1
_rel="beta1"
pkgrel=3
pkgdesc="LuxCoreRender is a physically correct, unbiased rendering engine."
arch=('x86_64')
url="https://www.luxcorerender.org/"
license=('Apache')
depends=(openimageio boost blosc embree glfw-x11 gtk3 opencl-icd-loader)
optdepends=("opencl-driver: for gpu acceleration"
"python-pyside: for pyluxcoretools gui")
makedepends=(git doxygen cmake python-pyside-tools opencl-headers)
conflicts=(luxrays-hg)
provides=(luxrays)
options=('!buildflags')
source=("https://github.com/LuxCoreRender/LuxCore/archive/${pkgname}_v${pkgver}${_rel}.tar.gz"
"python.patch"
"glfw.patch"
)
md5sums=('ac04f8dea232ebafc619afed152dad56'
'21b963e5f66d2c8c6a50bebcf9f0fe07'
'624f2be4cb431f6a4cfcc968d6263ac2')
prepare() {
cd ${srcdir}/LuxCore-${pkgname}_v${pkgver}${_rel}
msg "python.patch"
patch -Np1 < ../python.patch
msg "glfw.patch"
patch -Np1 < ../glfw.patch
}
build() {
cd ${srcdir}/LuxCore-${pkgname}_v${pkgver}${_rel}
mkdir -p build && cd build
cmake -DPYTHON_V=3 ..
make
}
package() {
cd ${srcdir}/LuxCore-${pkgname}_v${pkgver}${_rel}/build
install -d -m755 ${pkgdir}/usr/{bin,include,lib}
install -m755 bin/* ${pkgdir}/usr/bin
install -m644 lib/* ${pkgdir}/usr/lib
cp -a ../include ${pkgdir}/usr
# install pyluxcore to the Python search path
# _pypath=`pacman -Ql python | sed -n '/\/usr\/lib\/python[^\/]*\/$/p' | cut -d" " -f 2`
_pypath=`python -c 'import sys;print("/usr/lib/python{}.{}".format(sys.version_info.major,sys.version_info.minor))'`
install -d -m755 ${pkgdir}/${_pypath}
mv ${pkgdir}/usr/lib/pyluxcore.so ${pkgdir}/${_pypath}
}
# vim:set ts=2 sw=2 et:
|