PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Maintainer : bartus <arch-user-repoᘓbartus.33mail.com>
# shellcheck disable=SC2034
pkgname=luxcorerender-git
_fragment="#branch=blender2.80" #last working
pkgver=2.2alpha1.r423.gce80403e5
pkgrel=1
pkgdesc="Physically correct, unbiased rendering engine."
arch=('x86_64')
url="https://www.luxcorerender.org/"
license=('Apache')
depends=(oidn openimageio boost-libs blosc embree glfw-x11 gtk3 opencl-icd-loader)
optdepends=("opencl-driver: for gpu acceleration"
            "pyside2: for pyluxcoretools gui")
makedepends=(boost git doxygen cmake pyside2-tools opencl-headers)
conflicts=(luxrays-hg luxcorerender)
provides=(luxrays luxcorerender)
options=('!buildflags')
source=("git+https://github.com/LuxCoreRender/LuxCore.git${_fragment}"
        "python.patch"
        "glfw.patch"
        "boost016900_serialization.patch"
        )
md5sums=('SKIP'
         '8e2fd7337fe6afaf5b2801426837f600'
         'e2a20172b7b7ac92a7002b6218afe327'
         '52f097678654151e2b5427d271a7e69d')

pkgver() {
  cd ${srcdir}/LuxCore
#  git describe --long --tags | sed 's/^luxcorerender_v//;s/beta/\.beta/;;s/\([^-]*-g\)/r\1/;s/-/./g'
  printf "%s.r%d.g%s" "2.2alpha1" $(git rev-list --count luxcorerender_v2.2alpha1..HEAD) $(git log --pretty=format:'%h' -n 1)
} 


prepare() {
  cd ${srcdir}/LuxCore
  git apply -v ${srcdir}/*.patch
}

build() {
  _pyver=$(python -c "from sys import version_info; print(\"%d%d\" % (version_info[0],version_info[1]))")
  cd ${srcdir}/LuxCore
  mkdir -p build && cd build
  ((TRAVIS)) && {
    suppress_warnings="-Wno-implicit-fallthrough -Wno-class-memaccess"
    CFLAGS="$CFLAGS $suppress_warnings"
    CXXFLAGS="$CXXFLAGS $suppress_warnings"
  }
  msg "cflags=\"$CFLAGS\""
  msg "cxxflags=\"$CXXFLAGS\""

  cmake -DPYTHON_V=${_pyver} ..
  make
}

package() {
  cd ${srcdir}/LuxCore/build

  install -d -m755 ${pkgdir}/usr/{bin,include,lib}
  install -m755 bin/* ${pkgdir}/usr/bin
  install -m644 lib/* ${pkgdir}/usr/lib
  cp -a ../include ${pkgdir}/usr
  for file in ${pkgdir}/usr/include/*/*.in; do mv $file ${file%.in}; done

  # install pyluxcore to the Python search path
  #  _pypath=`pacman -Ql python | sed -n '/\/usr\/lib\/python[^\/]*\/$/p' | cut -d" " -f 2`
  _pypath=`python -c 'import sys;print("/usr/lib/python{}.{}".format(sys.version_info.major,sys.version_info.minor))'`
  install -d -m755 ${pkgdir}/${_pypath}
  mv ${pkgdir}/usr/lib/pyluxcore.so ${pkgdir}/${_pypath}
}

# vim:set ts=2 sw=2 et: