blob: f8d4b1d2071b4b9949bcee93d1ae65ead21bb34b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer : bartus <arch-user-repoᘓbartus.33mail.com>
# shellcheck disable=SC2034
_name="luxcorerender"
_ver_tag="luxcorerender_v2.2"
{ IFS='.'; read _ver_major _ver_minor; ((_ver_minor++)); unset IFS; } <<<${_ver_tag#luxcorerender_v}
pkgname=${_name}-git
pkgver=2.3.r80.gc68d73748
epoch=2
pkgrel=1
pkgdesc="Physically correct, unbiased rendering engine."
arch=('x86_64')
url="https://www.luxcorerender.org/"
license=('Apache')
depends=(oidn openimageio boost-libs blosc embree glfw-x11 gtk3 opencl-icd-loader)
optdepends=("opencl-driver: for gpu acceleration"
"pyside2: for pyluxcoretools gui")
makedepends=(boost git doxygen cmake pyside2-tools opencl-headers)
conflicts=(luxrays-hg luxcorerender)
provides=(luxrays luxcorerender=${epoch}:${_ver_major}.${_ver_minor})
options=('!buildflags')
source=("${_name}::git+https://github.com/LuxCoreRender/LuxCore.git${_fragment}"
"python.patch"
"glfw.patch"
"boost016900_serialization.patch"
)
md5sums=('SKIP'
'8e2fd7337fe6afaf5b2801426837f600'
'e2a20172b7b7ac92a7002b6218afe327'
'52f097678654151e2b5427d271a7e69d')
pkgver() {
cd ${srcdir}/${_name}
[ -v _ver_tag ] && printf %d.%d.r%s.g%s $_ver_major $_ver_minor $(git rev-list ${_ver_tag}..HEAD --count) $(git log --pretty=format:'%h' -n 1) \
|| git describe --long --tags | sed 's/^luxcorerender_v//;s/beta/\.beta/;;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd ${srcdir}/${_name}
git apply -v ${srcdir}/*.patch
}
build() {
_pyver=$(python -c "from sys import version_info; print(\"%d%d\" % (version_info[0],version_info[1]))")
mkdir -p ${srcdir}/build && cd ${srcdir}/build
((TRAVIS)) && {
suppress_warnings="-Wno-implicit-fallthrough -Wno-class-memaccess"
CFLAGS="$CFLAGS $suppress_warnings"
CXXFLAGS="$CXXFLAGS $suppress_warnings"
}
msg "cflags=\"$CFLAGS\""
msg "cxxflags=\"$CXXFLAGS\""
cmake -DPYTHON_V=${_pyver} ${srcdir}/${_name}
make
}
package() {
cd ${srcdir}/build
install -d -m755 ${pkgdir}/usr/{bin,include,lib}
install -m755 bin/* ${pkgdir}/usr/bin
install -m644 lib/* ${pkgdir}/usr/lib
cp -a ${srcdir}/${_name}/include ${pkgdir}/usr
for file in ${pkgdir}/usr/include/*/*.in; do mv $file ${file%.in}; done
# install pyluxcore to the Python search path
# _pypath=`pacman -Ql python | sed -n '/\/usr\/lib\/python[^\/]*\/$/p' | cut -d" " -f 2`
_pypath=`python -c 'import sys;print("/usr/lib/python{}.{}".format(sys.version_info.major,sys.version_info.minor))'`
install -d -m755 ${pkgdir}/${_pypath}
mv ${pkgdir}/usr/lib/pyluxcore.so ${pkgdir}/${_pypath}
}
# vim:set ts=2 sw=2 et:
|