blob: 8d9fe00cc99a4a75585fd45b238344190ad9d244 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Peter Mattern <pmattern@arcor.de>
# Contributor: Yen Chi Hsuan <yan12125@gmail.com>
# Contributor: Jerome Leclanche <jerome@leclan.ch>
_pkgname=lxqt-panel
pkgname=$_pkgname-git
pkgver=0.11.0.7.gf73d164
pkgrel=1
pkgdesc='The LXQt desktop panel'
arch=('i686' 'x86_64')
url='https://github.com/lxde/lxqt-panel'
license=('GPL2')
depends=(
"alsa-lib" "libpulse" "lm_sensors" "libstatgrab" "libsysstat-git"
"solid"
"menu-cache" "libxcomposite" "lxmenu-data" "libdbusmenu-qt5"
"lxqt-globalkeys"
)
makedepends=("git" "cmake" "qt5-tools")
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://github.com/lxde/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --always | sed "s/-/./g"
}
build() {
mkdir -p build
cd build
cmake "$srcdir/$_pkgname" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=/usr/lib
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|