PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: txtsd <aur.archlinux@ihavea.quest>
# Contributor: Faerbit <faerbit@gmail.com>

pkgname=lxqt_wallet
_pkgname=${pkgname//_/-}
pkgver=4.0.2
pkgrel=1
pkgdesc='Secure information storage for LXQt'
arch=('x86_64')
url='https://github.com/lxqt/lxqt_wallet'
license=('BSD-2-Clause')
depends=(
  'gcc-libs'
  'glib2'
  'glibc'
  'libgcrypt'
  'libglvnd'
  'qt6-base'
)
makedepends=(
  'cmake'
  'kwallet'
  'libsecret'
  'qt6-tools'
)
optdepends=(
  'libsecret: support for Gnome libsecret password storage'
  'kwallet: support for KDE wallet storage'
)
options=(!debug)
source=("https://github.com/mhogomchungu/lxqt_wallet/releases/download/${pkgver}/${_pkgname}-${pkgver}.tar.xz")
sha256sums=('3dbfc24555e88f6dd8aa79c2bf22e455f82d6a332e95418b08788d7adc226e50')

prepare() {
  cd "${_pkgname}-${pkgver}"

  cmake -S . -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release  \
    -DNOSECRETSUPPORT=false \
    -DNOKDESUPPORT=false \
    -DCMAKE_INSTALL_LIBDIR=lib
}

build() {
  cd "${_pkgname}-${pkgver}"

  cmake --build build
}

package() {
    cd "${_pkgname}-${pkgver}"

    DESTDIR="${pkgdir}" cmake --install build
    install -Dm644 'LICENSE' "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}