blob: 2d49ac39cb88a54771d0de8c4b1440e08f8aa862 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: Jason Chu <jason@archlinux.org>
pkgname=lyx
pkgver=2.3.7
pkgrel=3
pkgdesc="An advanced WYSIWYM document processor & LaTeX front-end"
arch=(x86_64)
url="https://www.${pkgname}.org"
depends=(qt5-svg texlive-basic python imagemagick enchant hunspell
libmythes file hicolor-icon-theme desktop-file-utils)
makedepends=(boost bc)
optdepends=('rcs: built-in version control system'
'texlive-latexextra: float wrap support'
'python: support for python scripts')
license=(GPL)
backup=('etc/lyx/lyxrc.dist')
options=('emptydirs' '!lto')
source=(https://ftp.lip6.fr/pub/${pkgname}/stable/${pkgver::4}x/${pkgname}-${pkgver}-1.tar.gz{,.sig}
lyxrc.dist)
validpgpkeys=('FE66471B43559707AFDAD955DE7A44FAC7FB382D') # LyX Release Manager (Signing LyX tarballs and binaries) <sanda@lyx.org>
sha512sums=('e3d936127b43ebc0f62aa6179fbc9cd00610ad5c6fd8946c85f6963e4bf10140babdb961234d85dc1f4d56dfd16eb12810764701d6e8501e6864e3ce6e8d596d'
'SKIP'
'eef777cf6033a7b1e04700f33068b07309f8d5c6931c16927305dafb3a00fd46d4b536149349ab56b7455e7dea195c8889da2b6fbf9caa9e76bc0557f9358bc3')
prepare() {
# Expand the automake compatibility version
sed -i 's/2.71/2.7\[1-9\]/' "${pkgname}-${pkgver}"/autogen.sh
}
build() {
cd ${pkgname}-${pkgver}
./autogen.sh
./configure \
--prefix=/usr \
--enable-qt5 \
--without-included-boost \
--without-included-mythes
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
# install appdata
install -Dm644 lib/appdata.xml "$pkgdir"/usr/share/metainfo/lyx.appdata.xml
# install default config file
install -Dm644 "${srcdir}/lyxrc.dist" "${pkgdir}/etc/lyx/lyxrc.dist"
ln -sf /etc/lyx/lyxrc.dist "${pkgdir}/usr/share/lyx/lyxrc.dist"
}
|