blob: 845b9ac93d31bc4d8b60d2577822a5ef2778f0ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
pkgname=macchatgpt
_pkgname=MacChatGPT
pkgver=1.0.0
_electronversion=23
pkgrel=3
pkgdesc="A desktop application which runs ChatGPT easily and free of charge."
arch=('x86_64')
url="https://github.com/justinhartman/MacChatGPT"
license=("custom")
conflicts=("${pkgname}")
depends=(
"electron${_electronversion}"
)
makedepends=(
'gendesk'
'npm'
'nodejs'
'git'
)
source=(
"${pkgname}-${pkgver}::git+${url}.git#tag=${pkgver}"
"${pkgname}.sh"
)
sha256sums=('SKIP'
'8915ca75d453698df81f7f3305cce6869f4261d754d90f0c3724b73c7b24ca84')
build() {
sed -e "s|@electronversion@|${_electronversion}|" \
-e "s|@appname@|${pkgname}|g" \
-e "s|@appasar@|app|g" \
-i "${srcdir}/${pkgname}.sh"
gendesk -q -f -n --categories "Utility" --name "${_pkgname}" --exec "${pkgname}"
cd "${srcdir}/${pkgname}-${pkgver}"
export npm_config_build_from_source=true
export npm_config_cache="${srcdir}/.npm_cache"
export ELECTRON_SKIP_BINARY_DOWNLOAD=1
export SYSTEM_ELECTRON_VERSION="$(electron${_electronversion} -v | sed 's/v//g')"
export ELECTRONVERSION="${_electronversion}"
npm install
npm run package:linux:x64
}
package() {
install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
install -Dm755 -d "${pkgdir}/usr/lib/${pkgname}"
cp -r "${srcdir}/${pkgname}-${pkgver}/dist/build/${_pkgname}-linux-x64/resources/app" "${pkgdir}/usr/lib/${pkgname}"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/assets/icons/png/512x512.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -Dm644 "${srcdir}/${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/dist/build/${_pkgname}-linux-x64/LICENSE"* -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|