blob: a02ba2855fc986a5624bed1cce29eda12c7ba3bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Chih-Hsuan Yen <yan12125@gmail.com>
pkgname=macports-base
pkgver=2.5.3
pkgrel=2
epoch=1
pkgdesc='The MacPorts command-line client'
url='https://www.macports.org/'
arch=('i686' 'x86_64')
license=('BSD')
depends=('curl' 'openssl' 'sqlite')
# tcl: MacPorts comes with its own vendored tclsh, while a system interpreter
# is still needed to build tcllib
makedepends=('tcl' 'nmtree')
optdepends=(
'rsync: for syncing sources via rsync'
'nmtree: for building ports'
)
source=("https://distfiles.macports.org/MacPorts/MacPorts-$pkgver.tar.bz2"{,.asc})
sha256sums=('5e2b31674f7e0108b63865aeeee4414d793645ee8faef7c9aa23c0ae72ce51d1'
'SKIP')
validpgpkeys=(
'C403793657236DCF2E580C0201FF673FB4AAE6CD' # Joshua Root <jmr@macports.org>
)
backup=(opt/local/etc/macports/archive_sites.conf
opt/local/etc/macports/macports.conf
opt/local/etc/macports/pubkeys.conf
opt/local/etc/macports/sources.conf
opt/local/etc/macports/variants.conf)
build() {
cd MacPorts-$pkgver
# provide paths manually so that these packages are not necessray during building
MAN=/usr/bin/man \
MTREE=/usr/bin/mtree \
RSYNC=/usr/bin/rsync \
./configure \
--enable-readline
make
}
package() {
cd MacPorts-$pkgver
make DESTDIR="$pkgdir" install
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|