summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ebc15ba1d710287eff8a314396aaef116b8252b3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
# Maintainer      :  Kr1ss $(echo \<kr1ss+x-yandex+com\>|sed s/\+/./g\;s/\-/@/)
# Upstream author :  Roland Puntaier <roland [dot] puntaier [at] gmail [dot] com>
# Upstream author :  Luke Smith <luke [at] lukesmith [dot] xyz>


pkgname=mailwizard-git

pkgver() {
  cd "${pkgname%-git}"
  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
pkgver=r730.89f8ae6
pkgrel=2

pkgdesc='Configure neomutt, isync, getmail and msmtp with pass for passwords'
arch=('x86_64')
url="https://github.com/rpuntaie/${pkgname%-git}"
license=('GPL3')

provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}" 'mutt-wizard')

makedepends=('git')
depends=('neomutt' 'isync' 'getmail' 'msmtp' 'notmuch-runtime' 'pass' 'urlscan')
optdepends=('imagemagick: view images inside of the neomutt TUI'
            'w3m: view HTML email and images inside of the neomutt TUI'
            'lynx: view HTML email inside of the neomutt TUI'
            'links: view HTML email inside of the neomutt TUI'
            'elinks: view HTML email inside of the neomutt TUI'
            'abook: contact store and tab completion'
            'cronie: auto-sync mails - alt.: fcron'
            'fcron: auto-sync mails - alt.: cronie'
            'libnotify: enable desktop notifications about new mail'
            'dunst: enable desktop notifications about new mail'
            'pam-gnupg: automatically unlock gpg keys at session login')
#checkdepends=('bash-bats')

options=('zipman')

changelog=changelog.txt
install=wizard.install
source=("git+$url"
        'migrationhelper')
sha256sums=('SKIP'
            '34682620297727b9bf93670b84592050d59181e682d3867cd56aefedbd67243f')


#check() {
#  cd "${pkgname%-git}"
#  ./dotests
#}

package() {
  cd "${pkgname%-git}"
  make DESTDIR="$pkgdir" -s install
  install -m755 ../migrationhelper -t"$pkgdir/usr/share/${pkgname%-git}/"
  install -Dm644 README.rst -t"$pkgdir/usr/share/doc/${pkgname%-git}/"
}


# vim: ts=2 sw=2 et ft=PKGBUILD: