PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: Emanuel Couto <unit73e@gmail.com>

_prjname=makehuman
pkgname=makehuman-git
pkgver=r2602.b3e9b869
pkgrel=1
pkgdesc="Parametrical modeling program for creating human bodies (git latest)"
arch=('any')
url="http://www.makehumancommunity.org/"
license=('AGPL3')
depends=('python' 'python-numpy' 'python-pyqt5' 'python-opengl' 'qt5-svg')
makedepends=('git' 'git-lfs')
provides=('makehuman')
conflicts=('makehuman')
source=("git+https://github.com/makehumancommunity/${_prjname}.git")
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/${_prjname}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/${_prjname}/makehuman"

	# Build as detailed on readme
	python download_assets_git.py
	python compile_models.py
	python compile_proxies.py
	python compile_targets.py
}

package() {
	cd "$srcdir/${_prjname}"

	# No standard UNIX structure so install in opt
	install -d -m755 "$pkgdir/opt/makehuman"
	cp -R makehuman/* "$pkgdir/opt/makehuman"
	
	# Creates a symlink to the binary
	install -d m755 "$pkgdir/usr/bin"
	ln -s "/opt/makehuman/makehuman.py" "$pkgdir/usr/bin/makehuman"
}