blob: fa7721c8579f3279e61c8b8aadd15e367f1edc42 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
# Contributor: Olaf Bauer <hydro@freenet.de>
pkgname=makemkv-cli
pkgver=1.17.7
pkgrel=1
pkgdesc='DVD and Blu-ray to MKV converter and network streamer - CLI only'
arch=('i686' 'x86_64')
url='https://www.makemkv.com'
license=('LGPL' 'MPL' 'custom')
depends=(
'ffmpeg'
'java-runtime'
'openssl-1.1'
)
makedepends=(
'less'
)
provides=('makemkv')
conflicts=('makemkv')
install=makemkv.install
source=(
"${url}/download/makemkv-bin-${pkgver}.tar.gz"
"${url}/download/makemkv-oss-${pkgver}.tar.gz"
makemkvcon.1
)
b2sums=('adc54191fd445832b9c4805400746e42d1b3261d076299b5e34beb1f13d80bf7bcbd113699f3d28fce5e21bb8f810a40927924b3d9c7250467d1979b1bf4f72b'
'18652db1d72ea7287e7e38706afc589e6fe8fb1fbf9d4e24770b9a2bfe670a464b2c21b7c543b23d3c6234f40048358d944b123897c4f569beb31faac8ef3eb7'
'a318361982271bee3db2fa6f3e2b51afd7fe35f3dcb821c24bc21f8189be74cf9093559dbf9689eedd458226b30ddf59333af10ef509dc850331639b9035be39')
build() {
cd makemkv-oss-${pkgver}
CFLAGS="$CFLAGS -std=c++11" CC=gcc CXX=g++ ./configure --prefix=/usr --disable-gui
make
}
package() {
cd makemkv-oss-${pkgver}
make DESTDIR="${pkgdir}" install
cd "${srcdir}"/makemkv-bin-${pkgver}
make DESTDIR="${pkgdir}" install
install -Dm644 src/eula_en_linux.txt "${pkgdir}"/usr/share/licenses/${pkgname}/eula_en_linux.txt
cd "${srcdir}"
install -Dm644 -t "${pkgdir}"/usr/share/man/man1/ makemkvcon.1
}
|