blob: dff0865afe75d76d8a3db3d25aa4690fb763814f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: trya <tryagainprod@gmail.com>
pkgname=mamepgui-git
pkgver=r37.2efd8b7
pkgrel=1
pkgdesc="Frontend for SDLMAME/SDLMESS based on MAME Plus!"
arch=('i686' 'x86_64')
url="http://sourceforge.net/projects/mameplus"
license=('custom:WTFPL')
depends=('qt4' 'quazip-qt4')
makedepends=('git')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}=1.6.0")
replaces=("${pkgname%-git}-svn")
optdepends=('sdlmame: port of MAME/MESS using SDL')
source=('mamepgui::git+https://github.com/svn2github/mamepgui.git'
'COPYING')
md5sums=('SKIP'
'389a9e29629d1f05e115f8f05c283df5')
pkgver() {
cd "$srcdir/${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/${pkgname%-git}"
# disable static compilation and SDL 1.3 linking
sed -e 's|CONFIG += build_static|#CONFIG += build_static|' \
-e 's|CONFIG += build_sdl|#CONFIG += build_sdl|' \
-i common_settings.pri
# use included libraries instead of installed ones
sed -e 's|LIBS += -L./lib/$${OSDIR}|QMAKE_LIBDIR += ./lib/$${OSDIR}|' \
-e 's|LIBS += -lquazip -llzma|LIBS += -lquazip -llzma -lz|' \
-e 's|TARGETDEPS +=|#TARGETDEPS +=|' \
-e 's|./lib/$${OSDIR}/libquazip.a|#./lib/$${OSDIR}/libquazip.a|' \
-e 's|./lib/$${OSDIR}/liblzma.a|#./lib/$${OSDIR}/liblzma.a|' \
-i mamepgui.pro
}
build() {
cd "$srcdir/${pkgname%-git}"
# build included liblzma.a (system one is not compatible)
cd lzma
qmake-qt4
make
# build mamepgui
cd ..
lrelease-qt4 mamepgui.pro
qmake-qt4
make
}
package() {
# install license
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
# install executable
install -Dm755 "$srcdir/${pkgname%-git}/bin/mamepgui" "$pkgdir/usr/bin/mamepgui"
}
|