PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Daniel Chen <danielchen04 at hotmail dot ca>

pkgname=mandown-git
pkgver=r211.e85a310
pkgrel=1
pkgdesc="Comic/manga/webtoon downloader and CBZ/EPUB/PDF converter"
url="https://github.com/potatoeggy/mandown"
replaces=()
arch=("any")
license=("AGPL3")
depends=(
	"python-requests"
	"python-typer"
	"python-feedparser"
	"python-beautifulsoup4"
	"python-slugify"
	"python-lxml"
	"python-natsort"
	"python-filetype"
	"python-comicon"
	"python-pillow"
)
makedepends=("git" "python-build" "python-installer" "python-poetry-core")
optdepends=(
	"pyside6: Graphical interface"
)
provides=()
conflicts=("mandown")
source=("git+$url.git")
sha256sums=("SKIP")

pkgver() {
  cd "$srcdir/mandown"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$srcdir/mandown"
    python -m build --wheel --no-isolation
}

package() {
    cd "$srcdir/mandown"
    python -m installer --destdir="$pkgdir" dist/*.whl
}