blob: f18f9e0d3c1edbf351de57898a9b44345c2a6db0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Darvin Delgado <dnmodder at gmail dot com>
pkgname=mangohud-git
pkgver=0.7.1.r0.g48d8426
pkgrel=1
pkgdesc="A Vulkan overlay layer for monitoring FPS, temperatures, CPU/GPU load and more."
url='https://github.com/flightlessmango/MangoHud'
license=('MIT')
arch=('x86_64')
makedepends=('git' 'appstream' 'cmocka' 'glslang' 'libxnvctrl' 'meson' 'nlohmann-json' 'python-mako' 'vulkan-headers')
depends=('dbus' 'fmt' 'gcc-libs' 'glew' 'hicolor-icon-theme' 'libglvnd' 'libx11' 'python-matplotlib' 'python-numpy' 'sdl2' 'spdlog' 'vulkan-icd-loader')
optdepends=('libxnvctrl: NVIDIA GPU stats by XNVCtrl')
provides=('mangohud')
conflicts=('mangohud' 'mangohud-common-git')
source=("$pkgname::git+$url")
sha512sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
local meson_options=(
--wrap-mode=nofallback
-Dwith_wayland=enabled
$pkgname
)
arch-meson "${meson_options[@]}" build
meson compile -C build
}
package() {
meson install -C build --destdir "$pkgdir"
install -Dm 0664 "$pkgname/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|