1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: envolution
# Contributor: Samuel Fernando Mesa Giraldo <samuelmesa@linuxmail.org>
# Contributor: Marcos Piccinini <x@nofxx.com>
# Contributor: Jonathan Hudson <jh+arch@daria.co.uk>
# shellcheck shell=bash disable=SC2034,SC2154
pkgname=mapserver
pkgver=8.6.0
pkgrel=1
pkgdesc="Platform for publishing spatial data and interactive mapping applications to the web"
arch=(i686 x86_64)
license=("Apache-2.0" "BSD-2-Clause")
url="http://www.mapserver.org"
depends=(
gdal
proj
libpng
freetype2
fribidi
fcgi
libjpeg-turbo
zlib
curl
libxml2
geos
gcc-libs
libxslt
pcre2
glibc
cairo
giflib
harfbuzz
protobuf-c
python
python-pillow
postgresql-libs
)
makedepends=(cmake swig)
provides=(python-mapserver)
source=("http://download.osgeo.org/mapserver/mapserver-${pkgver}.tar.gz")
md5sums=('e6f15c414e7ada32b4a17fa9da12fd7b')
build() {
cd "${pkgname}-${pkgver}"
mkdir -p build
cd build
#The following options are enabled by default
# WITH_PROJ, WITH_WMS, WITH_FRIBIDI,
# WITH_HARFBUZZ, WITH_ICONV, WITH_CAIRO,
# WITH_FCGI, WITH_GEOS, WITH_POSTGIS,
# WITH_GDAL, WITH_OGR, WITH_WFS,
# WITH_WCS, WITH_LIBXML2, WITH_GIF.
#svgcairo broken in AUR
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DWITH_SVGCAIRO=OFF \
../ >../configure.out.txt
make
}
package() {
cd "${pkgname}-${pkgver}/build"
make DESTDIR=${pkgdir} install
#Copy the headers a include for ZooWPS project
install -d "$pkgdir"/usr/include/mapserver
install -d "$pkgdir"/usr/share/mapserver
install -d "$pkgdir"/opt/mapserver/test/
install -Dm644 "${srcdir}/${pkgname}-${pkgver}"/build/*.h "$pkgdir"/usr/include/mapserver/
cp -rfv "${srcdir}/${pkgname}-${pkgver}"/share/ogcapi "$pkgdir"/usr/share/mapserver
cp -rfv "${srcdir}/${pkgname}-${pkgver}"/tests/* "$pkgdir"/opt/mapserver/test
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/src/flatgeobuf/LICENSE" \
${pkgdir}/usr/share/licenses/${pkgname}/FlatGeoBuf-LICENSE
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/src/flatgeobuf/include/flatbuffers/LICENSE" \
${pkgdir}/usr/share/licenses/${pkgname}/FlatBuffers-LICENSE
}
# vim:set ts=2 sw=2 et:
|