blob: 0cd2fd9ba6c499e6d7c49e95a06cc430681663f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
pkgname=marble-git
pkgver=v15.03.97.271.g61eb85f
pkgrel=1
pkgdesc="Desktop Globe. (GIT version)"
arch=('i686' 'x86_64')
url="https://www.kde.org/applications/system/marble"
license=('GPL')
provides=('marble')
conflicts=('marble' 'marble-qt' 'kdeedu-marble' )
depends=('qt5-webkit'
'kparts'
'knewstuff'
'opencv'
'hicolor-icon-theme'
)
makedepends=('cmake'
'git'
'gpsd'
'quazip-qt5'
'shapelib'
'qextserialport-qt5'
'libwlocate'
'phonon-qt5'
'extra-cmake-modules'
'qt5-webkit'
'krunner'
'python'
)
optdepends=('gpsd: position information via gpsd'
'quazip-qt5: reading and displaying .kmz files'
'shapelib: reading and displaying .shp files'
'qextserialport-qt5: reading from serial port in APRS plugin'
'libwlocate: Position information based on neighboring WLAN networks'
'phonon-qt5: That enables the use of audio and video content'
'krunner: Krunner plugin for marble')
source=('git://anongit.kde.org/marble.git')
sha1sums=('SKIP')
install=marble-git.install
pkgver() {
cd marble
echo "$(git describe --long --tags | tr - .)"
}
prepare() {
mkdir -p build
# fix installation designer plugins path
sed 's|LIB_SUFFIX}/plugins|LIB_SUFFIX}/qt/plugins|g' -i marble/CMakeLists.txt
# only build the KDE app
sed -e '/mobile/d' \
-e '/qt/d' \
-e '/Quick/d' \
-e '/touch/d' \
-i marble/src/apps/CMakeLists.txt
}
build() {
cd build
cmake ../marble \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_INSTALL_DIR=lib \
-DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
-DBUILD_TESTING=OFF \
-DWITH_KF5=ON \
-DBUILD_MARBLE_EXAMPLES=ON \
-DBUILD_MARBLE_TOOLS=ON \
-DBUILD_MARBLE_TESTS=OFF \
-DMOBILE=OFF
make
}
package() {
make -C build DESTDIR="${pkgdir}" install
}
|