blob: 8c51456b8e11fe2d3f73f2a8b49ae58b6d1e2b2d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Aaron Bishop < erroneous at gmail >
pkgname=mariadb-connector-odbc
conflicts=('mariadb-connector-odbc-bin')
pkgver=3.1.11
_c_pkgver=3.1.11
pkgrel=3
pkgdesc="A standardized, LGPL licensed ODBC database driver for MariaDB"
arch=('x86_64' 'armv7h')
url="https://mariadb.com/kb/en/mariadb/mariadb-connector-odbc/"
license=('LGPL')
depends=('unixodbc>=2.3' 'openssl' 'zlib')
makedepends=('git' 'cmake')
source=("https://downloads.mariadb.org/interstitial/connector-odbc-${pkgver}/${pkgname}-${pkgver}-ga-src.tar.gz"
"https://downloads.mariadb.org/interstitial/connector-c-${_c_pkgver}/mariadb-connector-c-${_c_pkgver}-src.tar.gz"
"ConnectorName.patch")
sha256sums=('d81a35cd9c9d2e1e732b7bd9ee704eb83775ed74bcc38d6cd5d367a3fc525a34'
'3e6f6c399493fe90efdc21a3fe70c30434b7480e8195642a959f1dd7a0fa5b0f'
'cec4b170608fb6b7d29315d49f82c031cee8b05778eb3fc13f735ff0c4d1de6c')
install=mariadb-connector-odbc.install
prepare() {
cd mariadb-connector-c-${_c_pkgver}-src
patch -p1 < ../ConnectorName.patch
cd ..
cd $pkgname-$pkgver-ga-src
[ -d libmariadb ] || ln -s ../mariadb-connector-c-${_c_pkgver}-src libmariadb
cd ..
rm -Rf build
mkdir build
}
build() {
cd build
cmake \
-DCMAKE_BUILD_TYPE=RELEASE \
-DWITH_EXTERNAL_ZLIB=ON \
-DWITH_OPENSSL=ON \
-DWITH_SSL=OPENSSL \
-DINSTALL_LIB_SUFFIX=lib \
-DCMAKE_INSTALL_PREFIX=/usr \
-DMARIADB_UNIX_ADDR=/run/mysqld/mysqld.sock \
../$pkgname-$pkgver-ga-src
make
}
package() {
cd build
DESTDIR="$pkgdir" cmake -DCOMPONENT=ODBCLibs -P cmake_install.cmake
if [ -f "$pkgdir/usr/lib/mariadb/libmaodbc.so" ]; then
mv "$pkgdir/usr/lib/mariadb/libmaodbc.so" "$pkgdir/usr/lib/libmaodbc.so"
rmdir "$pkgdir/usr/lib/mariadb"
fi
}
|