blob: e20751bff2a7f45ed7ee972f553aaac6b72e2b4d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Josip Ponjavic <josipponjavic at gmail dot com>
# Contributor:
pkgname=marker-git
pkgver=2018.03.09.r87.g4e0d3ef6
pkgrel=1
pkgdesc='Markdown editor for linux made with Gtk+-3.0'
arch=('x86_64')
url='https://github.com/fabiocolacio/Marker'
license=('GPL3')
depends=('gtksourceview3' 'gtkspell3' 'webkit2gtk')
makedepends=('git' 'meson')
optdepends=('pandoc: export to HTML, PDF, RTF, OTF, DOCX, LaTeX')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
options=(!buildflags)
source=("${pkgname%-*}::git+${url}.git"
'scidown::git+https://github.com/Mandarancio/scidown.git'
'charter::git+https://github.com/Mandarancio/charter.git'
'tinyexpr::git+https://github.com/codeplea/tinyexpr.git')
sha256sums=('SKIP' 'SKIP' 'SKIP' 'SKIP')
pkgver() {
cd ${pkgname%-*}
git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
cd ${pkgname%-*}
git submodule init
git config submodule.src/scidown.url "$srcdir/scidown"
git submodule update src/scidown
cd src/scidown
git submodule init
git config submodule.src/charter.url "$srcdir/charter"
git submodule update src/charter
cd src/charter
git submodule init
git config submodule.src/tinyexpr.url "$srcdir/tinyexpr"
git submodule update src/tinyexpr
#fix "Cant get charter to work #187"
sed -i 's/en_US/C/' ${srcdir}/${pkgname%-*}/src/scidown/src/charter/src/svg.c
}
build() {
arch-meson ${pkgname%-*} build
ninja -C build
}
package() {
DESTDIR="$pkgdir" ninja -C build install
}
|