PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Mitch Bigelow <ipha00@gmail.com>

pkgname=masscan-git
pkgver=706.9065684
pkgrel=1
pkgdesc="TCP port scanner, spews SYN packets asynchronously, scanning entire Internet in under 5 minutes"
arch=('i686' 'x86_64')
url="https://github.com/robertdavidgraham/masscan"
license=('AGPL')
depends=('libpcap')
makedepends=('git')
provides=('masscan')
conflicts=('masscan')
source=("$pkgname::git+https://github.com/robertdavidgraham/masscan.git")
md5sums=('SKIP')

pkgver() {
	cd "$pkgname"
	printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$pkgname"
	make
}

check() {
	cd "$pkgname"
	make regress	
}

package() {
	cd "$pkgname"

	# make install fails with spaces in ${pkgdir}. Install manually
	install -D -m755 bin/masscan "${pkgdir}/usr/bin/masscan"

	install -D -m664 doc/masscan.8 "${pkgdir}/usr/share/man/man8/masscan.8"
	install -D -m664 LICENSE "${pkgdir}/usr/share/licenses/masscan/LICENSE"
}