blob: 632fe2bb2a43b3e726d6b60cb34231c928b8640f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# Maintainer: Patrick Goetz <pgoetz at mail dot utexas dot edu>
# Contributor: Doug Newgard <scimmia at archlinux dot org>
# Contributor: Jiachen Yang <farseerfc@gmail.com>
# Contributor: Miguel Revilla <yo@miguelrevilla.com>
# Contributor: Ferik <djferik at gmail dot com>
pkgname=masterpdfeditor
pkgver=5.9.89
pkgrel=3
pkgdesc='A complete solution for viewing, creating and editing PDF files'
url='https://code-industry.net/free-pdf-editor/'
arch=('x86_64')
license=('custom')
makedepends=('patchelf')
source_x86_64=("https://code-industry.net/public/master-pdf-editor-${pkgver}-qt5.x86_64.tar.gz")
sha1sums_x86_64=('9701c8475d5efc7940f232f06c882e5bf9275566')
package() {
depends=('libgl' 'pkcs11-helper' 'qt5-base' 'qt5-svg' 'qt5-declarative' 'sane')
install -d "$pkgdir"{/opt/,/usr/bin/}
cp -a --no-preserve=ownership master-pdf-editor-${pkgver%%.*} "$pkgdir/opt/"
cd "$pkgdir/opt/master-pdf-editor-${pkgver%%.*}"
ln -sr masterpdfeditor${pkgver%%.*} -t "$pkgdir/usr/bin/"
install -Dm644 usr/share/applications/net.code-industry.masterpdfeditor${pkgver%%.*}.desktop -t "$pkgdir/usr/share/applications/"
install -Dm644 license_en.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
find usr/share/icons -type f -exec install -Dm644 "{}" "$pkgdir/{}" \;
patchelf --remove-rpath masterpdfeditor${pkgver%%.*}
}
|