blob: b9c96c4c7bc406587a94d6162ef7d8577888645e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Newb I the Newbd <czbd hostedon o2 halfacolon pl>
# Contributor: Martin Wimpress <code@flexion.org>
_ver=1.16
_pkgbase=mate-control-center
pkgname=${_pkgbase}-gtk2
pkgver=${_ver}.1
pkgrel=3
pkgdesc="The Control Center for MATE (GTK2 version)"
url="http://mate-desktop.org"
arch=('i686' 'x86_64')
license=('GPL')
depends=('mate-menus-gtk2' 'mate-settings-daemon-gtk2' 'marco-gtk2' 'libunique' 'libxss')
makedepends=('intltool' 'itstool')
groups=('mate-gtk2')
conflicts=("${_pkgbase}")
provides=("${_pkgbase}")
source=("http://pub.mate-desktop.org/releases/${_ver}/${_pkgbase}-${pkgver}.tar.xz")
sha1sums=('49f65c992fdc27e0c5c57cd57e7143813b67d76b')
build() {
cd "${srcdir}/${_pkgbase}-${pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--localstatedir=/var \
--with-gtk=2.0 \
--disable-update-mimedb
#https://bugzilla.gnome.org/show_bug.cgi?id=656231
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd "${srcdir}/${_pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -f "${pkgdir}/usr/share/applications/mimeinfo.cache"
}
|