PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Oleg Shparber <trollixx+aur@gmail.com>

_gitname=material-design-icons
pkgbase=material-icons-git
pkgname=("otf-${pkgbase}" "ttf-${pkgbase}")
pkgver=4.0.0.r83.g6745d95590b
pkgrel=3
pkgdesc="Material design icons is the official icon set from Google."
url='https://github.com/google/material-design-icons'
arch=('any')
license=('Apache')
makedepends=('git')
provides=("otf-material-icons=${pkgver}" "ttf-material-icons=${pkgver}")
source=("git+${url}.git")
sha256sums=('SKIP')

pkgver() {
    cd "${_gitname}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package_otf-material-icons-git() {
    cd "${_gitname}"
    install -Dm644 font/*.otf -t "${pkgdir}"/usr/share/fonts/OTF
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_ttf-material-icons-git() {
    cd "${_gitname}"
    install -Dm644 font/*.ttf -t "${pkgdir}"/usr/share/fonts/TTF
    install -Dm644 variablefont/*.ttf -t "${pkgdir}"/usr/share/fonts/TTF
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}